cmake_minimum_required(VERSION 3.22)

project(SATTARI_AUTO_PITCH_PLUGIN VERSION 0.1.0)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

if(NOT TARGET juce::juce_audio_utils)
    add_subdirectory(${CMAKE_CURRENT_LIST_DIR}/../../third_party/JUCE ${CMAKE_BINARY_DIR}/third_party/JUCE)
endif()

juce_add_plugin(SattariAutoPitch
    COMPANY_NAME "Sattari"
    IS_SYNTH FALSE
    NEEDS_MIDI_INPUT FALSE
    NEEDS_MIDI_OUTPUT FALSE
    IS_MIDI_EFFECT FALSE
    EDITOR_WANTS_KEYBOARD_FOCUS TRUE
    COPY_PLUGIN_AFTER_BUILD TRUE
    PLUGIN_MANUFACTURER_CODE Satr
    PLUGIN_CODE Ap01
    FORMATS AU VST3 Standalone
    PRODUCT_NAME "Sattari Auto Pitch")

juce_generate_juce_header(SattariAutoPitch)

target_sources(SattariAutoPitch
    PRIVATE
        src/PluginProcessor.cpp
        src/PluginEditor.cpp)

find_package(PkgConfig QUIET)
if(PkgConfig_FOUND)
    pkg_check_modules(RUBBERBAND QUIET IMPORTED_TARGET rubberband)
endif()

set(SATTARI_AUTOPITCH_RUBBERBAND_LIBS "")
if(RUBBERBAND_FOUND)
    target_compile_definitions(SattariAutoPitch PRIVATE SATTARI_AUTOPITCH_HAS_RUBBERBAND=1)
    target_include_directories(SattariAutoPitch PRIVATE ${RUBBERBAND_INCLUDE_DIRS})
    list(APPEND SATTARI_AUTOPITCH_RUBBERBAND_LIBS PkgConfig::RUBBERBAND)
else()
    target_compile_definitions(SattariAutoPitch PRIVATE SATTARI_AUTOPITCH_HAS_RUBBERBAND=0)
endif()

target_compile_definitions(SattariAutoPitch
    PUBLIC
        JUCE_WEB_BROWSER=0
        JUCE_USE_CURL=0
        JUCE_VST3_CAN_REPLACE_VST2=0)

target_link_libraries(SattariAutoPitch
    PRIVATE
        juce::juce_audio_utils
        ${SATTARI_AUTOPITCH_RUBBERBAND_LIBS}
    PUBLIC
        juce::juce_recommended_config_flags
        juce::juce_recommended_lto_flags
        juce::juce_recommended_warning_flags)

add_executable(AutoPitchCoreContract
    EXCLUDE_FROM_ALL
        tests/auto_pitch_core_contract.cpp
        src/PluginProcessor.cpp
        src/PluginEditor.cpp)

add_dependencies(AutoPitchCoreContract SattariAutoPitch)

target_include_directories(AutoPitchCoreContract
    PRIVATE
        src
        ${CMAKE_CURRENT_BINARY_DIR}/SattariAutoPitch_artefacts/JuceLibraryCode
        ${RUBBERBAND_INCLUDE_DIRS})

target_compile_definitions(AutoPitchCoreContract
    PUBLIC
        JucePlugin_Build_Standalone=1
        JUCE_WEB_BROWSER=0
        JUCE_USE_CURL=0
        JUCE_VST3_CAN_REPLACE_VST2=0
        SATTARI_AUTOPITCH_HAS_RUBBERBAND=$<BOOL:${RUBBERBAND_FOUND}>)

target_link_libraries(AutoPitchCoreContract
    PRIVATE
        juce::juce_audio_utils
        ${SATTARI_AUTOPITCH_RUBBERBAND_LIBS}
    PUBLIC
        juce::juce_recommended_config_flags
        juce::juce_recommended_lto_flags
        juce::juce_recommended_warning_flags)
